class_name SimNPC
extends RefCounted

@export var DEBUG_LOGS := true

const TASK_STATE_IDLE := "idle"
const TASK_STATE_TRAVELING := "traveling"
const TASK_STATE_WORKING := "working"
const TASK_STATE_COMPLETE := "complete"

var id: int
var npc_name: String
var profession: String
var hunger: float
var energy: float
var strength: float
var intelligence: float
var current_task: String = "idle"
var task_state: String = TASK_STATE_IDLE
var position: Vector3

var is_starving := false

var task_duration := 0.0
var task_progress := 0.0
var task_complete := true

func _init(
	_id: int,
	_npc_name: String,
	_profession: String,
	_strength: float,
	_intelligence: float
) -> void:
	id = _id
	npc_name = _npc_name
	profession = _profession
	strength = _strength
	intelligence = _intelligence
	hunger = randf_range(20.0, 80.0)
	energy = randf_range(40.0, 100.0)
	position = Vector3(randf_range(-8.0, 8.0), 0.0, randf_range(-8.0, 8.0))

func simulate_tick(village: SimVillage) -> void:
	hunger += 5.0 * village.food_modifier
	energy -= 2.0

	hunger = clamp(hunger, 0.0, 100.0)
	energy = clamp(energy, 0.0, 100.0)

	is_starving = hunger >= 90.0

	if is_starving:
		energy -= 8.0

	energy = clamp(energy, 0.0, 100.0)

	if task_state == TASK_STATE_IDLE or task_state == TASK_STATE_COMPLETE:
		choose_new_task(village)
		return

	if task_state == TASK_STATE_TRAVELING:
		return

	if task_state == TASK_STATE_WORKING:
		task_progress += 1.0

		if task_progress >= task_duration:
			task_complete = true
			task_state = TASK_STATE_COMPLETE

func choose_new_task(village: SimVillage) -> void:
	if hunger > 75.0:
		if village.food > 0:
			set_task("eat", 2.0)
		else:
			set_task("gather_food", 5.0)
		return

	if energy < 30.0:
		set_task("rest", 4.0)
		return

	var best_task := choose_best_work_task(village)

	match best_task:
		"gather_food":
			set_task("gather_food", 5.0)
		"gather_wood":
			set_task("gather_wood", 5.0)
		"patrol":
			set_task("patrol", 6.0)
		"study":
			set_task("study", 6.0)
		_:
			set_task("wander", 4.0)

func choose_best_work_task(village: SimVillage) -> String:
	var food_score := calculate_task_score(
		"gather_food",
		village.food_priority,
		village.food,
		15.0,
		30.0,
		3.0,
		1.5,
		"farmer"
	)

	var wood_score := calculate_task_score(
		"gather_wood",
		village.wood_priority,
		village.wood,
		10.0,
		20.0,
		2.5,
		1.0,
		"woodcutter"
	)

	var safety_score := calculate_task_score(
		"patrol",
		village.safety_priority,
		village.safety,
		30.0,
		50.0,
		3.0,
		1.5,
		"guard"
	)

	var knowledge_score := calculate_task_score(
		"study",
		village.knowledge_priority,
		village.knowledge,
		10.0,
		25.0,
		1.5,
		0.75,
		"scholar"
	)

	var best_task := "gather_food"
	var best_score := food_score

	if wood_score > best_score:
		best_task = "gather_wood"
		best_score = wood_score

	if safety_score > best_score:
		best_task = "patrol"
		best_score = safety_score

	if knowledge_score > best_score:
		best_task = "study"
		best_score = knowledge_score

	return best_task
	
func calculate_task_score(
	task_name: String,
	base_priority: float,
	resource_amount: float,
	critical_threshold: float,
	low_threshold: float,
	critical_bonus: float,
	low_bonus: float,
	preferred_profession: String
) -> float:
	var score := base_priority

	if resource_amount < critical_threshold:
		score += critical_bonus
	elif resource_amount < low_threshold:
		score += low_bonus

	if profession == preferred_profession:
		score += 2.0

	score += randf_range(0.0, 0.5)

	if DEBUG_LOGS:
		print(
			"[SimNPC] ",
			npc_name,
			" score ",
			task_name,
			" = ",
			score
		)

	return score

func set_task(task: String, duration: float) -> void:
	current_task = task
	task_duration = duration
	task_progress = 0.0
	task_complete = false
	task_state = TASK_STATE_TRAVELING

func start_working() -> void:
	if task_state != TASK_STATE_TRAVELING:
		return

	task_state = TASK_STATE_WORKING
	task_progress = 0.0
	task_complete = false